/* Set Timer for Scripted NPC Reactions */
IF %BGT_VAR%
Global("X#DynahMatch","GLOBAL",1)
Global("X#DynaheirRomanceActive","GLOBAL",1)
Global("X#DYReactionTimerSet","GLOBAL",0)
InParty(Myself)
THEN
RESPONSE #100
SetGlobal("X#DYReactionTimerSet","GLOBAL",1)
RealSetGlobalTimer("X#DYReactionTime","GLOBAL",DYROM_TIMER)
END

/* Set Romance Match */
IF %BGT_VAR%
Global("X#DynahMatch","GLOBAL",0)
InParty(Myself)
GlobalGT("X#DyFriendTalk","GLOBAL",1)
Gender(Player1,MALE)
!Global("P#BranwenRomanceActive","GLOBAL",2)
!Alignment(Player1,MASK_EVIL)
!Alignment(Player1,CHAOTIC_NEUTRAL)
OR(4)
Race(Player1,HUMAN)
Race(Player1,ELF)
Race(Player1,HALF_ELF)
Race(Player1,HALFORC)
ReputationGT(Player1,10)
CheckStatGT(Player1,9,INT)
CheckStatGT(Player1,9,WIS)
!HasItemEquiped("%tutu_var%BELT05",Player1) //girdle of gender bender
THEN
RESPONSE #100
SetGlobal("X#DynahMatch","GLOBAL",1)
END

/* Set Romance Break if Branwen is at 2 */
IF %BGT_VAR%
Global("P#BranwenRomanceActive","GLOBAL",2)
!Global("X#DynaheirRomanceInactive","GLOBAL",1)
Global("X#DynaheirRomanceActive","GLOBAL",1)
InParty(Myself)
InParty("branwen")
THEN
RESPONSE #100
SetGlobal("X#DynaheirRomanceInactive","GLOBAL",1)
SetGlobal("X#DynaRomCutByOther","GLOBAL",1)
END

IF %BGT_VAR%
Global("P#BranwenRomanceActive","GLOBAL",1)
!Global("X#DynaheirRomanceInactive","GLOBAL",1)
Global("X#DynaheirRomanceActive","GLOBAL",2)
InParty(Myself)
InParty("branwen")
THEN
RESPONSE #100
SetGlobal("P#BranwenRomanceActive","GLOBAL",3)
SetGlobal("P#BranRomCutByOther","GLOBAL",1)
END

/* LoveTalks */
IF %BGT_VAR%
Global("X#DynahMatch","GLOBAL",1)
Global("X#DynaheirRomanceActive","GLOBAL",0)
Global("X#DYLoveTalk","GLOBAL",0)
InParty(Myself)
THEN
RESPONSE #100
RealSetGlobalTimer("X#DYLoveTalkTime","GLOBAL",DYROM_TIMER)
SetGlobal("X#DYLoveTalk","GLOBAL",1)
SetGlobal("X#DynaheirRomanceActive","GLOBAL",1)
END

IF %BGT_VAR%
RealGlobalTimerExpired("X#DYLoveTalkTime","GLOBAL")
ReputationGT(Player1,11)
!Global("X#DynaheirRomanceInactive","GLOBAL",1)
Global("X#DynaheirRomanceActive","GLOBAL",1)
!Global("X#DynaheirBhaalLoop","GLOBAL",1)
!AreaType(DUNGEON)
OR(11)
Global("X#DYLoveTalk","GLOBAL",1)
Global("X#DYLoveTalk","GLOBAL",3)
Global("X#DYLoveTalk","GLOBAL",5)
Global("X#DYLoveTalk","GLOBAL",11)
Global("X#DYLoveTalk","GLOBAL",13)
Global("X#DYLoveTalk","GLOBAL",15)
Global("X#DYLoveTalk","GLOBAL",17)
Global("X#DYLoveTalk","GLOBAL",19)
Global("X#DYLoveTalk","GLOBAL",23)
Global("X#DYLoveTalk","GLOBAL",27)
Global("X#DYLoveTalk","GLOBAL",31)
InParty(Myself)
!StateCheck(Player1,CD_STATE_NOTVALID)
!StateCheck(Myself,CD_STATE_NOTVALID)
CombatCounter(0)
!See([ENEMY])
THEN
RESPONSE #100
IncrementGlobal("X#DYLoveTalk","GLOBAL",1)
END

IF %BGT_VAR%
RealGlobalTimerExpired("X#DYLoveTalkTime","GLOBAL")
ReputationGT(Player1,11)
!Global("X#DynaheirRomanceInactive","GLOBAL",1)
Global("X#DynaheirRomanceActive","GLOBAL",2)
!Global("X#DynaheirBhaalLoop","GLOBAL",1)
!AreaType(DUNGEON)
OR(2)
Global("X#DYLoveTalk","GLOBAL",39)
Global("X#DYLoveTalk","GLOBAL",47)
InParty(Myself)
!StateCheck(Player1,CD_STATE_NOTVALID)
!StateCheck(Myself,CD_STATE_NOTVALID)
CombatCounter(0)
!See([ENEMY])
THEN
RESPONSE #100
IncrementGlobal("X#DYLoveTalk","GLOBAL",1)
END

IF %BGT_VAR%
RealGlobalTimerExpired("X#DYLoveTalkTime","GLOBAL")
OR(14)
Global("X#DYLoveTalk","GLOBAL",2)
Global("X#DYLoveTalk","GLOBAL",4)
Global("X#DYLoveTalk","GLOBAL",6)
Global("X#DYLoveTalk","GLOBAL",8)
Global("X#DYLoveTalk","GLOBAL",10)
Global("X#DYLoveTalk","GLOBAL",12)
Global("X#DYLoveTalk","GLOBAL",14)
Global("X#DYLoveTalk","GLOBAL",16)
Global("X#DYLoveTalk","GLOBAL",18)
Global("X#DYLoveTalk","GLOBAL",20)
Global("X#DYLoveTalk","GLOBAL",24)
Global("X#DYLoveTalk","GLOBAL",26)
Global("X#DYLoveTalk","GLOBAL",28)
Global("X#DYLoveTalk","GLOBAL",32)
InParty(Myself)
!StateCheck(Player1,CD_STATE_NOTVALID)
!StateCheck(Myself,CD_STATE_NOTVALID)
THEN
RESPONSE #100
PlaySong(0)
PlaySound("dyrom1")
StartDialogueNoSet(Player1)
END

IF %BGT_VAR%
RealGlobalTimerExpired("X#DYLoveTalkTime","GLOBAL")
OR(9)
Global("X#DYLoveTalk","GLOBAL",34)
Global("X#DYLoveTalk","GLOBAL",36)
Global("X#DYLoveTalk","GLOBAL",38)
Global("X#DYLoveTalk","GLOBAL",40)
Global("X#DYLoveTalk","GLOBAL",42)
Global("X#DYLoveTalk","GLOBAL",44)
Global("X#DYLoveTalk","GLOBAL",46)
Global("X#DYLoveTalk","GLOBAL",48)
Global("X#DYLoveTalk","GLOBAL",50)
InParty(Myself)
!StateCheck(Player1,CD_STATE_NOTVALID)
!StateCheck(Myself,CD_STATE_NOTVALID)
THEN
RESPONSE #100
PlaySong(0)
PlaySound("dyrom2")
StartDialogueNoSet(Player1)
END

IF %BGT_VAR%
GlobalGT("X#DYLoveTalk","GLOBAL",32)
Global("X#DynaheirRomanceActive","GLOBAL",1)
!Global("X#DynaheirRomanceInactive","GLOBAL",1)
InParty(Myself)
THEN
RESPONSE #100
SetGlobal("X#DynaheirRomanceActive","GLOBAL",2)
END

IF %BGT_VAR%
Global("X#DYMagicItem","GLOBAL",1)
Global("X#DYLoveTalk","GLOBAL",45)
InParty(Myself)
!StateCheck(Player1,CD_STATE_NOTVALID)
!StateCheck(Myself,CD_STATE_NOTVALID)
ReputationGT(Player1,11)
!Global("X#DynaheirRomanceInactive","GLOBAL",1)
Global("X#DynaheirRomanceActive","GLOBAL",2)
!Global("X#DynaheirBhaalLoop","GLOBAL",1)
THEN
RESPONSE #100
SetGlobal("X#DYLoveTalk","GLOBAL",46)
END

IF %BGT_VAR%
!Global("X#DYMagicItem","GLOBAL",1)
Global("X#DYLoveTalk","GLOBAL",45)
THEN
RESPONSE #100
SetGlobal("X#DYLoveTalk","GLOBAL",47)
RealSetGlobalTimer("X#DYLoveTalkTime","GLOBAL",DYROM_TIMER)
END

IF %BGT_VAR%
Global("X#DYLoveTalk","GLOBAL",37)
InParty(Myself)
!StateCheck(Player1,CD_STATE_NOTVALID)
!StateCheck(Myself,CD_STATE_NOTVALID)
CombatCounter(0)
!See([ENEMY])
ReputationGT(Player1,11)
!Global("X#DynaheirRomanceInactive","GLOBAL",1)
Global("X#DynaheirRomanceActive","GLOBAL",2)
!Global("X#DynaheirBhaalLoop","GLOBAL",1)
THEN
RESPONSE #100
SetGlobal("X#DYLoveTalk","GLOBAL",38)
END

IF %BGT_VAR%
RealGlobalTimerExpired("X#DYLoveTalkTime","GLOBAL")
Global("X#DYLoveTalk","GLOBAL",29)
InParty(Myself)
!StateCheck(Player1,CD_STATE_NOTVALID)
!StateCheck(Myself,CD_STATE_NOTVALID)
CombatCounter(0)
!See([ENEMY])
ReputationGT(Player1,11)
!Global("X#DynaheirRomanceInactive","GLOBAL",1)
Global("X#DynaheirRomanceActive","GLOBAL",1)
!Global("X#DynaheirBhaalLoop","GLOBAL",1)
AreaType(CITY)
!AreaType(DUNGEON)
THEN
RESPONSE #100
SetGlobal("X#DYLoveTalk","GLOBAL",30)
END

IF %BGT_VAR%
RealGlobalTimerExpired("X#DYLoveTalkTime","GLOBAL")
Global("X#DYLoveTalk","GLOBAL",30)
Global("X#DYLoveSettaSpawn","GLOBAL",0)
InParty(Myself)
!StateCheck(Player1,CD_STATE_NOTVALID)
!StateCheck(Myself,CD_STATE_NOTVALID)
CombatCounter(0)
!See([ENEMY])
ReputationGT(Player1,11)
!Global("X#DynaheirRomanceInactive","GLOBAL",1)
Global("X#DynaheirRomanceActive","GLOBAL",1)
!Global("X#DynaheirBhaalLoop","GLOBAL",1)
AreaType(CITY)
!AreaType(DUNGEON)
THEN
RESPONSE #100
CreateCreatureObject("X#SETTA",Player1,0,0,0)
SetGlobal("X#DYLoveSettaSpawn","GLOBAL",1)
ActionOverride("X#SETTA",StartDialogueNoSet(Player1))
END

IF %BGT_VAR%
RealGlobalTimerExpired("X#DYLoveTalkTime","GLOBAL")
Global("X#DYLoveTalk","GLOBAL",25)
InParty(Myself)
!StateCheck(Player1,CD_STATE_NOTVALID)
!StateCheck(Myself,CD_STATE_NOTVALID)
CombatCounter(0)
!See([ENEMY])
ReputationGT(Player1,11)
Global("X#DynahMatch","GLOBAL",1)
!Global("X#DynaheirRomanceInactive","GLOBAL",1)
Global("X#DynaheirRomanceActive","GLOBAL",1)
!Global("X#DynaheirBhaalLoop","GLOBAL",1)
HPPercentLT(Player1,96)
THEN
RESPONSE #100
SetGlobal("X#DYLoveTalk","GLOBAL",26)
END

/* Morning After */
IF %BGT_VAR%
Global("X#DYLoveTalk","GLOBAL",9)
InParty(Myself)
!StateCheck(Player1,CD_STATE_NOTVALID)
!StateCheck(Myself,CD_STATE_NOTVALID)
CombatCounter(0)
!See([ENEMY])
ReputationGT(Player1,11)
!Global("X#DynaheirRomanceInactive","GLOBAL",1)
Global("X#DynaheirRomanceActive","GLOBAL",1)
!Global("X#DynaheirBhaalLoop","GLOBAL",1)
!AreaType(DUNGEON)
THEN
RESPONSE #100
IncrementGlobal("X#DYLoveTalk","GLOBAL",1)
END

/* BhaalTalks */
IF %BGT_VAR%
Global("X#BTTalk","GLOBAL",0)
InParty(Myself)
Global("P#KnowBhaal","GLOBAL",1)
PartyHasItem("%tutu_var%scrl2J")
Global("X#DynaheirBhaalLoop","GLOBAL",0)
THEN
RESPONSE #100
RealSetGlobalTimer("X#BTTalkTime","GLOBAL",DYROM_TIMER)
IncrementGlobal("X#BTTalk","GLOBAL",1)
SetGlobal("X#DynaheirBhaalLoop","GLOBAL",1)
END

IF %BGT_VAR%
RealGlobalTimerExpired("X#BTTalkTime","GLOBAL")
ReputationGT(Player1,11)
!Global("X#DynaheirRomanceInactive","GLOBAL",1)
OR(3)
Global("X#BTTalk","GLOBAL",1)
Global("X#BTTalk","GLOBAL",3)
Global("X#BTTalk","GLOBAL",5)
OR(2)
Global("X#DynaheirRomanceActive","GLOBAL",1)
Global("X#DynaheirRomanceActive","GLOBAL",2)
Global("X#DynaheirBhaalLoop","GLOBAL",1)
!AreaType(DUNGEON)
InParty(Myself)
!StateCheck(Player1,CD_STATE_NOTVALID)
!StateCheck(Myself,CD_STATE_NOTVALID)
CombatCounter(0)
!See([ENEMY])
THEN
RESPONSE #100
IncrementGlobal("X#BTTalk","GLOBAL",1)
END

IF %BGT_VAR%
RealGlobalTimerExpired("X#BTTalkTime","GLOBAL")
OR(3)
Global("X#BTTalk","GLOBAL",2)
Global("X#BTTalk","GLOBAL",4)
Global("X#BTTalk","GLOBAL",6)
InParty(Myself)
!StateCheck(Player1,CD_STATE_NOTVALID)
!StateCheck(Myself,CD_STATE_NOTVALID)
THEN
RESPONSE #100
PlaySong(0)
PlaySound("dyrom1")
StartDialogueNoSet(Player1)
END

IF %BGT_VAR%
InParty(Myself)
GlobalGT("X#BTTalk","GLOBAL",5)
Global("X#DynaheirBhaalLoop","GLOBAL",1)
GlobalGT("X#DynaheirBhaalBreak","GLOBAL",3)
THEN
RESPONSE #100
SetGlobal("X#DynaheirBhaalLoop","GLOBAL",3)
SetGlobal("X#DynaheirRomanceInactive","GLOBAL",1)
END

IF %BGT_VAR%
InParty(Myself)
GlobalGT("X#BTTalk","GLOBAL",5)
Global("X#DynaheirBhaalLoop","GLOBAL",1)
GlobalLT("X#DynaheirBhaalBreak","GLOBAL",4)
THEN
RESPONSE #100
SetGlobal("X#DynaheirBhaalLoop","GLOBAL",2)
END

/* Branwen Conflict */
IF %BGT_VAR%
Global("X#DYBRConflict","GLOBAL",0)
InParty(Myself)
InParty("branwen")
!Global("X#DynaheirRomanceInactive","GLOBAL",1)
Global("X#DynaheirRomanceActive","GLOBAL",1)
!Global("P#BranwenRomanceActive","GLOBAL",3)
Global("P#BranwenRomanceActive","GLOBAL",1)
GlobalGT("X#DYLoveTalk","GLOBAL",4)
GlobalGT("P#BRLoveTalk","GLOBAL",4)
THEN
RESPONSE #100
RealSetGlobalTimer("X#DYBRConflictTime","GLOBAL",DYROM_TIMER)
SetGlobal("X#DYBRConflict","GLOBAL",1)
END

IF %BGT_VAR%
RealGlobalTimerExpired("X#DYBRConflictTime","GLOBAL")
!Global("X#DynaheirRomanceInactive","GLOBAL",1)
Global("X#DynaheirRomanceActive","GLOBAL",1)
!Global("P#BranwenRomanceActive","GLOBAL",3)
Global("P#BranwenRomanceActive","GLOBAL",1)
OR(6)
Global("X#DYBRConflict","GLOBAL",1)
Global("X#DYBRConflict","GLOBAL",3)
Global("X#DYBRConflict","GLOBAL",5)
Global("X#DYBRConflict","GLOBAL",7)
Global("X#DYBRConflict","GLOBAL",9)
Global("X#DYBRConflict","GLOBAL",11)
InParty(Myself)
InParty("branwen")
THEN
RESPONSE #100
IncrementGlobal("X#DYBRConflict","GLOBAL",1)
END

IF %BGT_VAR%
RealGlobalTimerExpired("X#DYBRConflictTime","GLOBAL")
InParty(Myself)
InParty("branwen")
See(Player1)
See("branwen")
!StateCheck(Player1,CD_STATE_NOTVALID)
!StateCheck(Myself,CD_STATE_NOTVALID)
!StateCheck("branwen",CD_STATE_NOTVALID)
OR(3)
Global("X#DYBRConflict","GLOBAL",2)
Global("X#DYBRConflict","GLOBAL",8)
Global("X#DYBRConflict","GLOBAL",12)
THEN
RESPONSE #100
Interact(Player1)
END

IF %BGT_VAR%
RealGlobalTimerExpired("X#DYBRConflictTime","GLOBAL")
OR(3)
Global("X#DYBRConflict","GLOBAL",4)
Global("X#DYBRConflict","GLOBAL",6)
Global("X#DYBRConflict","GLOBAL",10)
InParty(Myself)
InParty("branwen")
See(Player1)
See("branwen")
!StateCheck(Player1,CD_STATE_NOTVALID)
!StateCheck(Myself,CD_STATE_NOTVALID)
!StateCheck("branwen",CD_STATE_NOTVALID)
THEN
RESPONSE #100
ActionOverride("branwen",Interact(Player1))
END

/* Dynaheir Initiated Flirts */
IF %BGT_VAR%
Global("Chapter","GLOBAL",%tutu_chapter_3%)
Global("%bgdreams%","GLOBAL",%bgdream2%)
Global("X#DyFlirt1","GLOBAL",0)
Global("X#DynahMatch","GLOBAL",1)
!Global("X#DynaheirRomanceInactive","GLOBAL",1)
InParty(Myself)
!StateCheck(Player1,CD_STATE_NOTVALID)
!StateCheck(Myself,CD_STATE_NOTVALID)
CombatCounter(0)
!See([ENEMY])
PartyRested()
THEN
RESPONSE #100
SetGlobal("X#DyFlirt1","GLOBAL",1)
END

IF %BGT_VAR%
Global("X#DyFlirt1","GLOBAL",1)
InParty(Myself)
!StateCheck(Player1,CD_STATE_NOTVALID)
!StateCheck(Myself,CD_STATE_NOTVALID)
THEN
RESPONSE #100
PlaySong(0)
PlaySound("dyrom1")
StartDialogueNoSet(Player1)
END

IF %BGT_VAR%
Global("X#DynahMatch","GLOBAL",1)
!Global("X#DynaheirRomanceInactive","GLOBAL",1)
Global("Chapter","GLOBAL",%tutu_chapter_4%)
Global("%bgdreams%","GLOBAL",%bgdream3%)
Global("X#DyFlirt2","GLOBAL",0)
InParty(Myself)
!StateCheck(Player1,CD_STATE_NOTVALID)
!StateCheck(Myself,CD_STATE_NOTVALID)
CombatCounter(0)
!See([ENEMY])
PartyRested()
THEN
RESPONSE #100
SetGlobal("X#DyFlirt2","GLOBAL",1)
END

IF %BGT_VAR%
Global("X#DyFlirt2","GLOBAL",1)
InParty(Myself)
!StateCheck(Player1,CD_STATE_NOTVALID)
!StateCheck(Myself,CD_STATE_NOTVALID)
THEN
RESPONSE #100
PlaySong(0)
PlaySound("dyrom1")
StartDialogueNoSet(Player1)
END

IF %BGT_VAR%
Global("X#DynahMatch","GLOBAL",1)
!Global("X#DynaheirRomanceInactive","GLOBAL",1)
Global("Chapter","GLOBAL",%tutu_chapter_5%)
Global("%bgdreams%","GLOBAL",%bgdream4%)
Global("X#DyFlirt3","GLOBAL",0)
InParty(Myself)
!StateCheck(Player1,CD_STATE_NOTVALID)
!StateCheck(Myself,CD_STATE_NOTVALID)
CombatCounter(0)
!See([ENEMY])
PartyRested()
THEN
RESPONSE #100
SetGlobal("X#DyFlirt3","GLOBAL",1)
END

IF %BGT_VAR%
Global("X#DyFlirt3","GLOBAL",1)
InParty(Myself)
!StateCheck(Player1,CD_STATE_NOTVALID)
!StateCheck(Myself,CD_STATE_NOTVALID)
THEN
RESPONSE #100
PlaySong(0)
PlaySound("dyrom1")
StartDialogueNoSet(Player1)
END

IF %BGT_VAR%
Global("X#DynahMatch","GLOBAL",1)
!Global("X#DynaheirRomanceInactive","GLOBAL",1)
Global("Chapter","GLOBAL",%tutu_chapter_6%)
Global("%bgdreams%","GLOBAL",%bgdream5%)
Global("X#DyFlirt4","GLOBAL",0)
InParty(Myself)
!StateCheck(Player1,CD_STATE_NOTVALID)
!StateCheck(Myself,CD_STATE_NOTVALID)
CombatCounter(0)
!See([ENEMY])
PartyRested()
THEN
RESPONSE #100
SetGlobal("X#DyFlirt4","GLOBAL",1)
END

IF %BGT_VAR%
Global("X#DyFlirt4","GLOBAL",1)
InParty(Myself)
!StateCheck(Player1,CD_STATE_NOTVALID)
!StateCheck(Myself,CD_STATE_NOTVALID)
THEN
RESPONSE #100
PlaySong(0)
PlaySound("dyrom1")
StartDialogueNoSet(Player1)
END

IF %BGT_VAR%
Global("Chapter","GLOBAL",%tutu_chapter_7%)
Global("X#DyFlirt5","GLOBAL",0)
Global("X#DynahMatch","GLOBAL",1)
!Global("X#DynaheirRomanceInactive","GLOBAL",1)
Global("%bgdreams%","GLOBAL",%bgdream6%)
InParty(Myself)
!StateCheck(Player1,CD_STATE_NOTVALID)
!StateCheck(Myself,CD_STATE_NOTVALID)
CombatCounter(0)
!See([ENEMY])
PartyRested()
THEN
RESPONSE #100
SetGlobal("X#DyFlirt5","GLOBAL",1)
END

IF %BGT_VAR%
Global("X#DyFlirt5","GLOBAL",1)
InParty(Myself)
!StateCheck(Player1,CD_STATE_NOTVALID)
!StateCheck(Myself,CD_STATE_NOTVALID)
THEN
RESPONSE #100
PlaySong(0)
PlaySound("dyrom1")
StartDialogueNoSet(Player1)
END

IF %BGT_VAR%
Global("X#DynahMatch","GLOBAL",1)
!Global("X#DynaheirRomanceInactive","GLOBAL",1)
Global("X#DynaTamokoSarevok","GLOBAL",1)
GlobalTimerExpired("X#DynaTamFlirt","GLOBAL")
Global("X#DyFlirt6","GLOBAL",0)
InParty(Myself)
!StateCheck(Player1,CD_STATE_NOTVALID)
!StateCheck(Myself,CD_STATE_NOTVALID)
CombatCounter(0)
!See([ENEMY])
THEN
RESPONSE #100
SetGlobal("X#DyFlirt6","GLOBAL",1)
END

IF %BGT_VAR%
Global("X#DyFlirt6","GLOBAL",1)
InParty(Myself)
!StateCheck(Player1,CD_STATE_NOTVALID)
!StateCheck(Myself,CD_STATE_NOTVALID)
THEN
RESPONSE #100
PlaySong(0)
PlaySound("dyrom1")
StartDialogueNoSet(Player1)
END

/* Dyna Delainy Kiss */
IF %BGT_VAR%
Global("X#DynaRomanceDurKiss","GLOBAL",1)
Global("X#DyFlirt7","GLOBAL",0)
InParty(Myself)
!StateCheck(Player1,CD_STATE_NOTVALID)
!StateCheck(Myself,CD_STATE_NOTVALID)
CombatCounter(0)
!See([ENEMY])
Global("X#DynahMatch","GLOBAL",1)
!Global("X#DynaheirRomanceInactive","GLOBAL",1)
THEN
RESPONSE #100
SetGlobal("X#DyFlirt7","GLOBAL",1)
END

IF %BGT_VAR%
Global("X#DyFlirt7","GLOBAL",1)
InParty(Myself)
!StateCheck(Player1,CD_STATE_NOTVALID)
!StateCheck(Myself,CD_STATE_NOTVALID)
THEN
RESPONSE #100
PlaySong(0)
PlaySound("dyrom1")
StartDialogueNoSet(Player1)
END
