/* CONTENTS */
/* Viconia banters w safana in an inn */
/* Viconia's thanks */
/* Eldoth, bring me some food */

/* Viconia banters w safana in an inn */
IF %BGT_VAR%
Global("X#SAVI1","LOCALS",1)
Global("X#VISA1","LOCALS",0)
RealGlobalTimerExpired("X#DreamTalk","GLOBAL")
InParty(Myself)
!StateCheck(Myself,CD_STATE_NOTVALID)
InParty("safana")
!StateCheck("safana",CD_STATE_NOTVALID)
CombatCounter(0)
!See([ENEMY])
See("safana")
OR(20)
AreaCheck("%Beregost_FeldepostsInn_L1%")
AreaCheck("%Beregost_JovialJuggler_L1%")
AreaCheck("%Beregost_RedSheaf_L1%")
AreaCheck("%Beregost_BurningWizard_L1%")
AreaCheck("%Nashkel_Inn%")
AreaCheck("%EBaldursGate_KeexieTavern_L1%")
AreaCheck("%EBaldursGate_ElfsongTavern_L1%")
AreaCheck("%EBaldursGate_Inn_L1%")
AreaCheck("%SEBaldursGate_Inn_L1%")
AreaCheck("%SEBaldursGate_Blade&Stars_L1%")
AreaCheck("%BaldursGateDocks_JopalinsTavern%")
AreaCheck("%SWBaldursGate_Tavern_L1%")
AreaCheck("%SWBaldursGate_YeOldeInn_L1%")
AreaCheck("%NWBaldursGate_Helm&Cloak_L1%")
AreaCheck("%NWBaldursGate_Tavern_L1%")
AreaCheck("%NBaldursGate_ThreeOldKegs_L1%")
AreaCheck("%NEBaldursGate_BlushingMermaid_L1%")
AreaCheck("%NEBaldursGate_SplurgingSturgeon_L2%")
AreaCheck("%FriendlyArmInn_L1%")
AreaCheck("%NEBaldursGate_SplurgingSturgeon_L1%")
THEN
RESPONSE #100
SetGlobal("X#VISA1","LOCALS",1)
RealSetGlobalTimer("X#DreamTalk","GLOBAL",180)
StartDialogueNoSet("safana")
END

/* Viconia's thanks */
IF %BGT_VAR%
Global("X#VIPC3","LOCALS",0)
RealGlobalTimerExpired("X#DreamTalk","GLOBAL")
InParty(Myself)
!StateCheck(Myself,CD_STATE_NOTVALID)
!StateCheck(Player1,CD_STATE_NOTVALID)
InMyArea(Player1)
CombatCounter(0)
!See([ENEMY])
THEN
RESPONSE #100
SetGlobal("X#VIPC3","LOCALS",1)
RealSetGlobalTimer("X#DreamTalk","GLOBAL",180)
StartDialogueNoSet(Player1)
END

/* Eldoth, bring me some food */
IF %BGT_VAR%
Global("X#VIEL1","LOCALS",0)
RealGlobalTimerExpired("X#DreamTalk","GLOBAL")
InParty(Myself)
!StateCheck(Myself,CD_STATE_NOTVALID)
InParty("eldoth")
!StateCheck("eldoth",CD_STATE_NOTVALID)
CombatCounter(0)
!See([ENEMY])
InMyArea("eldoth")
THEN
RESPONSE #100
SetGlobal("X#VIEL1","LOCALS",1)
RealSetGlobalTimer("X#DreamTalk","GLOBAL",180)
StartDialogueNoSet("eldoth")
END
