//EXTEND_TOP WSMITH01 13
//  IF ~OR(10)
//      PartyHasItem("bdbrac05")
//      PartyHasItem("bdhelm16")
//      PartyHasItem("GelJav0")
//      PartyHasItem("SPER02")
//      PartyHasItem("GelSpe6")
//      PartyHasItem("SPER05")
//      PartyHasItem("SPER07")
//      PartyHasItem("SPER08")
//      PartyHasItem("SPER11")
//      PartyHasItem("STAF14")
//  ~ THEN GOTO Gel_Crom_Hub
//END

EXTEND_TOP WSMITH01 59
  IF ~~ THEN REPLY ~Can you forge some custom items for me?~ GOTO Gel_Crom_Hub
END

EXTEND_TOP WSMITH01 13
  IF ~~ THEN REPLY ~Can you forge some custom items for me?~ GOTO Gel_Crom_Hub
END

APPEND WSMITH01

IF ~~ THEN BEGIN Gel_Crom_Hub
  SAY ~Hmmm... aye, I see ye have some unusual pieces here. Cromwell might be able to make something of them.~

  IF ~PartyHasItem("bdbrac05")~ THEN REPLY ~Can you improve these Stalker Gauntlets?~ GOTO Gel_StalkerGloves
  IF ~PartyHasItem("bdhelm16")~ THEN REPLY ~Can you improve this Circlet of Lost Souls?~ GOTO Gel_SoulCirclet
  IF ~PartyHasItem("GelJav0")~ THEN REPLY ~Can you improve this Throwing Spear?~ GOTO Gel_Jav1
  IF ~PartyHasItem("SPER02")~ THEN REPLY ~Can you make a stronger Throwing Spear?~ GOTO Gel_Jav2
  IF ~PartyHasItem("SPER07")~ THEN REPLY ~Can you combine the Unicorn Spear and Halcyon?~ GOTO Gel_Spear5
  IF ~PartyHasItem("SPER08")~ THEN REPLY ~Can you improve the Impaler?~ GOTO Gel_Spear6
  IF ~PartyHasItem("SPER11")~ THEN REPLY ~Can you complete Ixil's Impaler?~ GOTO Gel_SpearX
  IF ~PartyHasItem("STAF14")~ THEN REPLY ~Can you empower the Staff of the Woodlands?~ GOTO Gel_StaffW

  IF ~~ THEN REPLY ~Never mind.~ GOTO 13
END

IF ~~ THEN BEGIN Gel_StalkerGloves
  SAY ~Aye, I could reinforce those gauntlets with an ankheg shell. It'll cost ye 15,000 gold.~

  IF ~PartyHasItem("bdbrac05") PartyHasItem("misc12") PartyGoldGT(14999)~
    THEN REPLY ~Yes, let's do it.~
    DO ~
      TakePartyGold(15000)
      DestroyGold(15000)
      TakePartyItemNum("bdbrac05",1)
      DestroyItem("bdbrac05")
      TakePartyItemNum("misc12",1)
      DestroyItem("misc12")
      SetGlobal("GelForgeItem","GLOBAL",1)
      SetGlobal("GelForgeStuff","GLOBAL",1)
    ~ GOTO 56

  IF ~PartyHasItem("bdbrac05") !PartyHasItem("misc12")~
    THEN REPLY ~What am I missing?~
    GOTO Gel_StalkerMissing

  IF ~PartyGoldLT(15000)~
    THEN REPLY ~I do not have enough gold.~
    GOTO Gel_Crom_Hub

  IF ~~ THEN REPLY ~Not right now.~ GOTO Gel_Crom_Hub
END

IF ~~ THEN BEGIN Gel_StalkerMissing
  SAY ~Ye still need an ankheg shell for this work.~
  IF ~~ THEN REPLY ~I see.~ GOTO Gel_Crom_Hub
END

IF ~~ THEN BEGIN Gel_SoulCirclet
  SAY ~Aye, I could combine the Circlet of Lost Souls with the Helm of Vhailor. It'll cost ye 15,000 gold.~

  IF ~PartyHasItem("bdhelm16") PartyHasItem("WA2HELM") PartyGoldGT(14999)~
    THEN REPLY ~Yes, let's do it.~
    DO ~
      TakePartyGold(15000)
      DestroyGold(15000)
      TakePartyItemNum("bdhelm16",1)
      DestroyItem("bdhelm16")
      TakePartyItemNum("WA2HELM",1)
      DestroyItem("WA2HELM")
      SetGlobal("GelForgeItem","GLOBAL",2)
      SetGlobal("GelForgeStuff","GLOBAL",1)
    ~ GOTO 56

  IF ~PartyHasItem("bdhelm16") !PartyHasItem("WA2HELM")~
    THEN REPLY ~What am I missing?~
    GOTO Gel_SoulMissing

  IF ~PartyGoldLT(15000)~
    THEN REPLY ~I do not have enough gold.~
    GOTO Gel_Crom_Hub

  IF ~~ THEN REPLY ~Not right now.~ GOTO Gel_Crom_Hub
END

IF ~~ THEN BEGIN Gel_SoulMissing
  SAY ~Ye still need the Helm of Vhailor for this work.~
  IF ~~ THEN REPLY ~I see.~ GOTO Gel_Crom_Hub
END

IF ~~ THEN BEGIN Gel_Jav1
  SAY ~Aye, I can combine that Throwing Spear with a Spear +1 for 500 gold.~
  IF ~PartyHasItem("GelJav0") PartyHasItem("SPER02") PartyGoldGT(499)~
    THEN REPLY ~Yes, do it.~ DO ~TakePartyGold(500) DestroyGold(500) TakePartyItemNum("GelJav0",1) DestroyItem("GelJav0") TakePartyItemNum("SPER02",1) DestroyItem("SPER02") SetGlobal("GelForgeItem","GLOBAL",3) SetGlobal("GelForgeStuff","GLOBAL",1)~ GOTO 56
  IF ~~ THEN REPLY ~Not right now.~ GOTO Gel_Crom_Hub
END

IF ~~ THEN BEGIN Gel_Jav2
  SAY ~Aye, I can combine two Spears +1 for 2,500 gold and make a Throwing Spear +2.~
  IF ~NumItemsPartyGT("SPER02",1) PartyGoldGT(2499)~
    THEN REPLY ~Yes, do it.~
    DO ~TakePartyGold(2500)
        DestroyGold(2500)
        TakePartyItemNum("SPER02",2)
        DestroyItem("SPER02")
        SetGlobal("GelForgeItem","GLOBAL",4)
        SetGlobal("GelForgeStuff","GLOBAL",1)~
    GOTO 56
  IF ~~ THEN REPLY ~Not right now.~ GOTO Gel_Crom_Hub
END

IF ~~ THEN BEGIN Gel_Spear5
  SAY ~Aye, the Spear of the Unicorn and Halcyon can become something finer. It'll cost 5,000 gold.~
  IF ~PartyHasItem("SPER07") PartyHasItem("SPER09") PartyGoldGT(4999)~
    THEN REPLY ~Yes, do it.~ DO ~TakePartyGold(5000) DestroyGold(5000) TakePartyItemNum("SPER07",1) DestroyItem("SPER07") TakePartyItemNum("SPER09",1) DestroyItem("SPER09") SetGlobal("GelForgeItem","GLOBAL",5) SetGlobal("GelForgeStuff","GLOBAL",1)~ GOTO 56
  IF ~~ THEN REPLY ~Not right now.~ GOTO Gel_Crom_Hub
END

IF ~~ THEN BEGIN Gel_Spear6
  SAY ~Aye, I can join the Impaler with Ixi's Spike for 10,000 gold.~
  IF ~PartyHasItem("SPER08") PartyHasItem("DAGG23") PartyGoldGT(9999)~
    THEN REPLY ~Yes, do it.~ DO ~TakePartyGold(10000) DestroyGold(10000) TakePartyItemNum("SPER08",1) DestroyItem("SPER08") TakePartyItemNum("DAGG23",1) DestroyItem("DAGG23") SetGlobal("GelForgeItem","GLOBAL",6) SetGlobal("GelForgeStuff","GLOBAL",1)~ GOTO 56
  IF ~~ THEN REPLY ~Not right now.~ GOTO Gel_Crom_Hub
END

IF ~~ THEN BEGIN Gel_SpearX
  SAY ~Aye, I can bind Ixi's Nail to the improved Impaler. This is serious work: 30,000 gold.~
  IF ~PartyHasItem("SPER11") PartyHasItem("GelSpe6") PartyGoldGT(29999)~
    THEN REPLY ~Yes, do it.~ DO ~TakePartyGold(30000) DestroyGold(30000) TakePartyItemNum("SPER11",1) DestroyItem("SPER11") TakePartyItemNum("GelSpe6",1) DestroyItem("GelSpe6") SetGlobal("GelForgeItem","GLOBAL",7) SetGlobal("GelForgeStuff","GLOBAL",1)~ GOTO 56
  IF ~~ THEN REPLY ~Not right now.~ GOTO Gel_Crom_Hub
END

IF ~~ THEN BEGIN Gel_StaffW
  SAY ~Aye, with a Winter Wolf Pelt and a Demon Heart I can empower the Staff of the Woodlands.~
  IF ~PartyHasItem("STAF14") PartyHasItem("MISC01") PartyHasItem("MISC06")~
    THEN REPLY ~Yes, do it.~ DO ~TakePartyItemNum("STAF14",1) DestroyItem("STAF14") TakePartyItemNum("MISC01",1) DestroyItem("MISC01") TakePartyItemNum("MISC06",1) DestroyItem("MISC06") SetGlobal("GelForgeItem","GLOBAL",8) SetGlobal("GelForgeStuff","GLOBAL",1)~ GOTO 56
  IF ~~ THEN REPLY ~Not right now.~ GOTO Gel_Crom_Hub
END

END