BACKUP ~extra_kits/backup~
AUTHOR ~SubtleD~



ALWAYS
	INCLUDE ~extra_kits/lib/fl#add_kit_ee.tpa~


	DEFINE_ACTION_FUNCTION add_extra_kits INT_VAR extra_kits = 1 BEGIN

		OUTER_FOR (num_kits=1;num_kits<(extra_kits+1);++num_kits) BEGIN

		ADD_KIT ~D5_TEST%num_kits%~
		//___________________________________________________________________________________

		//WEAPON PROFICIENCIES_______________________________________________________________
		//11                                   T   S           F   Q             S S
		//10           L S                     W   C           L   U             W I
		//9            A M             B L S   O   I   W       A   A             O N
		//8            R A             A O H   H   M   A       I   R C   S       R G
		//7            G L           M S N O   A   I   R     H L   T R L H     2 D L 2                 E E E E E E E E E E E
		//6            E L       S   I T G R   N K T D H     A M   E O O O     H A E W E E E E E E E E X X X X X X X X X X X
		//5            S S   S B P   S A S T   D A A A A   S L O   R S N R   S A N W E X X X X X X X X T T T T T T T T T T T
		//4            W W   P L I   S R W S   E T R G M C P B R M S S G T D L N D E A T T T T T T T T R R R R R R R R R R R
		//3            O O B E U K A I D O W A D A W G M L E E N A T B B B A I D S A P R R R R R R R R A A A A A A A A A A A
		//2            R R O A N E X L S R O X S N A E E U A R I C A O O O R N E H P O A A A A A A A A 1 1 1 1 1 1 1 1 1 1 2
		//1            D D W R T D E E W D R E W A K R R B R D N E F W W W T G D I O N 2 3 4 5 6 7 8 9 0 1 2 3 4 5 6 7 8 9 0
		~D5_TEST%num_kits%      0 0 0 0 0 0 0 0~
		~D5_TEST%num_kits%      0 0 0 0 0 0 0 0 1 1 1 1 1 1 1 1 1 1 1 1 1 1 1 1 1 1 1 1 1 1 1 1 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0~

		//MINIMUM KIT STATS_________________________________________________________________
		//                 STR DEX CON INT WIS CHR
		~D5_TEST%num_kits%           0   0   0   0   0   0~

		//KIT STAT MODIFIERS________________________________________________________________
		//                 STR DEX CON INT WIS CHR
		~D5_TEST%num_kits%           0   0   0   0   0   0~

		//REQUIREMENTS TO DUAL TO THIS KIT__________________________________________________
		//                 STR DEX CON INT WIS CHR
		~D5_TEST%num_kits%           17  17  17  17  17  17~

		//REQUIREMENTS TO DUAL FROM THIS KIT________________________________________________
		//                 STR DEX CON INT WIS CHR
		~D5_TEST%num_kits%           15  15  15  15  15  15~

		//ALIGNMENT RESTRICTIONS____________________________________________________________
		//                 LG LN LE NG TN NE CG CN CE
		~D5_TEST%num_kits%           0  0  0  0  1  0  0  0  0~

		//DUAL CLASS OPTIONS________________________________________________________________
		//                 FT CL MA TH DR RA
		~D5_TEST%num_kits%           0  0  0  0  0  0~

		//KIT ABILITIES 2DA FILE_____________________________________________________________
		~extra_kits/D5_TEST.2da~

		//RACIAL KIT AVAILABILITY____________________________________________________________
		~~

		//UNUSABLE FLAGS AND KIT BASE CLASS__________________________________________________
		//CLASSES: Mage = 1, Fighter = 2, Cleric=3, Thief = 4, Bard = 5
		//         Paladin 6, Druid = 11, Ranger = 12, Sorcerer = 19
		//         Monk = 20
		~0x00004000 2~

		//HIGH LEVEL ABILITIES ABBREVIATION__________________________________________________
		~Fi0~

		//TOB STARTING EQUIPMENT_____________________________________________________________
		~LEAT14	* HELM07 BAG20 RING06 RING31 CLCK02 BOOT01 AMUL19 BRAC16 BELT06 AROW11,40 BULL03,40 BOLT06,40 POTN52,5 POTN04,2 POTN14,5 HAMM07 SW1H39 STAF08~

		//CHARACTER CREATION KIT DESCRIPTION________________________________________________
		SAY ~D5_TEST%num_kits%~
		SAY ~D5_TEST%num_kits%~
		SAY ~Test kit %num_kits%~
		//___________________________________________________________________________________

		//EE KIT EXTRAS______________________________________________________________________
		//
		ACTION_IF GAME_IS ~bgee bg2ee~ THEN BEGIN
			LAF fl#add_kit_ee
				INT_VAR
					briefdesc = RESOLVE_STR_REF (~D5_TEST%num_kits%~)
				STR_VAR
					kit_name = EVAL ~D5_TEST%num_kits%~
					clswpbon = ~1 0 2~
			END
		END
		//____________________________________________________________________________________

		END

	END

END


BEGIN ~With default kit reserve~
SUBCOMPONENT ~Kit equalizer~
	INCLUDE ~extra_kits/num_kits.ini~
	
	COPY_EXISTING ~kitlist.2da~ ~override~
		COUNT_2DA_ROWS 9 kit_count		
	BUT_ONLY_IF_IT_CHANGES
	ACTION_IF kit_count > kit_reserve THEN BEGIN
		FAIL ~Can't fill the kit list up to %kit_reseerve% kits as it is already %kit_count% long~
	END
	
	OUTER_SET kits_to_add = kit_reserve - kit_count
	LAF add_extra_kits INT_VAR extra_kits = kits_to_add END
	
	PRINT ~Padded with %kits_to_add% empty kits up to %kit_reserve% entries.~



BEGIN ~Interactive with instructions~
SUBCOMPONENT ~Kit equalizer~
	COPY_EXISTING ~kitlist.2da~ ~override~
		COUNT_2DA_ROWS 9 kit_count		
	BUT_ONLY_IF_IT_CHANGES
	
	OUTER_TEXT_SPRINT help 
		~Run the setup of this mod on all games you wish to play and enter the highest number of kits installed.~ 
	OUTER_TEXT_SPRINT help
		~%help%  Alternatively, enter any value you are confident is higher than the sum of standard and NPC kits.~
	PRINT ~%help%~
	PRINT ~You currently have %kit_count% kits installed.~
	
	OUTER_TEXT_SPRINT input ~~
	OUTER_WHILE NOT IS_AN_INT ~%input%~ OR input < kit_count OR input >= 255 BEGIN
		ACTION_READLN input
		ACTION_IF NOT IS_AN_INT ~%input%~ THEN BEGIN
			PRINT ~Please enter a valid number:~
		END ELSE ACTION_IF input < kit_count THEN BEGIN
			PRINT ~Please enter a number greater than %kit_count%:~
		END ELSE ACTION_IF input >= 255 THEN BEGIN
			PRINT ~Please enter a number lesser than 255:~
		END
	END
	OUTER_SET kits_to_add = input - kit_count
	
	LAF add_extra_kits INT_VAR extra_kits = kits_to_add END

	PRINT ~Padded with %kits_to_add% empty kits up to %input% entries.~