[(BG1, BG2) BUG] Item power levels (0813)

CamDawg

Background: Every effect in spells or items has a designated power level. When MGI blocks 1st-, 2nd-, and 3rd- level spells what it's really doing is blocking any effect with a power level of 1-3. By convention, unless an item descript says it 'casts X' Bioware was content to let abilities from items completely bypass any sort of spell protections. What we're doing here is setting a whole mess of effects to power level 0 (never blocked) to comply with this convention.

// fix power levels
COPY_EXISTING ~arow06.itm~   ~override~ // arrows of detonation - explosion has power 3
              ~arow08.itm~   ~override~ // arrows of fire - fire damage has power 6
              ~arow09.itm~   ~override~ // arrows of ice - cold damage has power 6
              ~ax1h07.itm~   ~override~ // bala's axe - miscast magic effects have power 3
              ~bolt03.itm~   ~override~ // bolt of lightning - electrical damage has power 6
              ~bolt05.itm~   ~override~ // bolt of polymorphing - polymorph effects are power 6
              ~bonedag.itm~  ~override~ // bone dagger attack item - slow effects have power 2, all other effects 0
              ~dart03.itm~   ~override~ // dart of stunning - stun effects have power 8
              ~dart04.itm~   ~override~ // dart of wounding - poison damage has power 0, poison portrait icon has power 8
              ~hamm03.itm~   ~override~ // ashideena - electrical damage has power 8
              ~potn26.itm~   ~override~ // potion of explosions
              ~potn27.itm~   ~override~ // potion of firebreath
              ~quasclaw.itm~ ~override~ // attack of quasit familiars - dex drain has power 4
              ~revent1.itm~  ~override~ // attack of revenants - paralyzation effects at power 1
              ~ring20.itm~   ~override~ // ring of energy
              ~scrl03.itm~   ~override~ // protection from acid
              ~scrl04.itm~   ~override~ // protection from cold
              ~scrl05.itm~   ~override~ // protection from electricity
              ~scrl06.itm~   ~override~ // protection from fire
              ~scrl08.itm~   ~override~ // protection from poison
              ~scrl09.itm~   ~override~ // protection from undead
              ~scrl15.itm~   ~override~ // protection from petrification
              ~shille.itm~   ~override~ // shillelagh - visual effect has power 1
              ~sw1h06.itm~   ~override~ // varscona - cold damage at power 8
              ~wand12.itm~   ~override~ // wand of wonder - all effects at power 0 except visuals at 8
              ~wolfwi1.itm~  ~override~ // attack of winter wolves - cold damage at power 1
              ~wolfwi2.itm~  ~override~ // attack of winter wolves - cold damage at power 1
  READ_LONG   0x64 "abil_off" ELSE 0
  READ_SHORT  0x68 "abil_num" ELSE 0
  READ_LONG   0x6a "fx_off"   ELSE 0
  FOR (index = 0 ; index < abil_num ; index = index + 1) BEGIN // cycle thru abilities
    READ_SHORT  (0x1e + "%abil_off%" + ("%index%" * 0x38)) "abil_fx_num"
    READ_SHORT  (0x20 + "%abil_off%" + ("%index%" * 0x38)) "abil_fx_idx"
    FOR (index2 = 0 ; index2 < abil_fx_num ; index2 = index2 + 1) BEGIN
      WRITE_BYTE ("%fx_off%" + 0x03 + (("%abil_fx_idx%" + "%index2%") * 0x30)) 0 // should bypass spell protections
    END
  END
  BUT_ONLY_IF_IT_CHANGES

Coriander

I'll put it in.

Nathan

Verified, this change has been implemented internally and should be present in the next build.

Avenger_teambg

I would not set a creature's attack to 0, by d&d conventions a magic attack is the same level as the creature, isn't it? Or something similar.
Otherwise the script was confirmed executed.

Bhryaen

Confirmed Applied:

Near Infinity shows all these now have all their sundry effects changed to Power 0:
AROW06
AROW08
AROW09
AX1H07
BOLT03
BOLT05
BONEDAG
DART03
DART04
HAMM03
POTN26
POTN27
QUASCLAW
RING02
SCRL03
SCRL04
SCRL05
SCRL06
SCRL08
SCRL09
SCRL15
SHILLE
SW1H06
WAND12
WOLFWI1
WOLFWI2

Confirmed not completely applied (not sure if this is actually an issue):

REVENT1 (Regeneration Effect set to Power 1)

SethDavis

I'll grab that one now

Potentially fixed - REVENT1 now has its regeneration power set to 0

Avenger_teambg

It was not an issue, as it was nonmagical (undispellable). But it is not a problem to clear it either.

Tanthalas

Used NI to check that REVENT1 now has its regeneration power set to 0.

I think I cna safely file this one as Fixed.