Looking to mod the "Thief Controlled" script (which I believe is Thief0.BS)

elminster

Specifically I was wondering how I would go about removing the requirement that an enemy not be in your line of sight when its activated (this is for the shadowdancer). I looked through it but not being particularly familiar with anything more than basic scripting for the game I'm not too sure what exactly is being used to restrict it from activating when enemies are in your line of sight. So help here would be appreciated.

CrevsDaak

IF
	Global("RR#THFS","LOCALS",0)
	HotKey(D)
THEN
	RESPONSE #100
		SetGlobal("RR#THFS","LOCALS",1)
		DisplayStringHead(Myself,25482) // Attempting to hide in shadows
END

IF
	Global("RR#THFS","LOCALS",1)
	HotKey(D)
THEN
	RESPONSE #100
		SetGlobal("RR#THFS","LOCALS",0)
		DisplayStringHead(Myself,25483) // Searching for traps
END

IF
	Global("RR#THFA","LOCALS",0)
	HotKey(V)
THEN
	RESPONSE #100
		SetGlobal("RR#THFA","LOCALS",1)
		DisplayStringHead(Myself,25488) // Attacking enemies
END

IF
	Global("RR#THFA","LOCALS",1)
	HotKey(V)
THEN
	RESPONSE #100
		SetGlobal("RR#THFA","LOCALS",0)
		DisplayStringHead(Myself,25489) // Not attacking enemies
END

IF
	Global("RR#THFS","LOCALS",0)
	ActionListEmpty()
	OR(2)
		!See([EVILCUTOFF])
		Global("RR#THFA","LOCALS",0)
	OR(2)
		Class(Myself,THIEF_ALL)
		Class(Myself,MONK)
	!ModalState(TURNUNDEAD)
	!ModalState(DETECTTRAPS)
THEN
	RESPONSE #100
		FindTraps()
END

IF
	Global("RR#THFS","LOCALS",1)
	!Kit(Myself,SHADOWDANCER)
	!GlobalTimerNotExpired("RR#HIDE","LOCALS")
	ActionListEmpty()
	!See([EVILCUTOFF])
	OR(3)
		Class(Myself,THIEF_ALL)
		Class(Myself,RANGER_ALL)
		Class(Myself,MONK)
	!ModalState(TURNUNDEAD)
	!ModalState(STEALTH)
THEN
	RESPONSE #100
		SetGlobalTimer("RR#HIDE","LOCALS",6)
		Hide()
END

IF
	Global("RR#THFS","LOCALS",1)
	Kit(Myself,SHADOWDANCER)
	!GlobalTimerNotExpired("RR#HIDE","LOCALS")
	ActionListEmpty()
	OR(3)
		Class(Myself,THIEF_ALL)
		Class(Myself,RANGER_ALL)
		Class(Myself,MONK)
	!ModalState(TURNUNDEAD)
	!ModalState(STEALTH)
THEN
	RESPONSE #100
		SetGlobalTimer("RR#HIDE","LOCALS",6)
		Hide()
END

IF
	Global("RR#THFA","LOCALS",1)
	ActionListEmpty()
	!StateCheck(Myself,STATE_INVISIBLE)
	CheckStatLT(Myself,1,SANCTUARY)
	See([EVILCUTOFF])
	!InParty([EVILCUTOFF])
THEN
	RESPONSE #100
		AttackReevaluate([EVILCUTOFF],30)
END

elminster

Sweet thanks!

elminster

Yea didn't seem to work for me when I tried it just now.